20 septiembre 2007

Creando aplicaciones MDI

Una aplicación MDI en Windows es aquella que contiene una ventana principal la cual que contiene a su vez ventanas hijas (al estilo Word o Excel). Cada ventana hija no puede salirse del marco de trabajo de la ventana padre aunque si puede minimizarse, maximizarse, etc.


A su vez no todas las ventanas creadas tienen que ser hijas de la ventana padre. Pueden crearse ventanas independientes ya sean normales o modales (una ventana modal es aquella que no permite acceder a ninguna otra hasta que se cierre, como los típicas ventanas de diálogo).

COMO CREAR UNA APLICACION MDI

Aunque el asistente de creación de proyectos de Delphi permite crear aplicaciones MDI, realmente no tiene mucha ciencia. Sólo hay que coger el formulario principal de la aplicación y cambiar su propiedad FormStyle a fsMDIForm. Con sólo hacer eso ya tenemos la ventana padre contenedora.

Para crear una ventana hija hay que hacer lo siguiente:

procedure TFormulario.MDIChildClick( Sender: TObject );
var
Form: TForm;
begin
Form := TForm.Create( Self );
Form.FormStyle := fsMDIChild;
Form.Caption := 'Ventana hija MDI';
Form.OnClose := AlCerrar;
Form.Show;
end;

Como puede apreciarse hemos creado una ventana y le hemos dicho que su estilo es fsMDIChild. También hemos asignado el evento OnClose para cerrar la ventana:

procedure TFormulario.AlCerrar( Sender: TObject; var Action: TCloseAction );
begin
Action := caFree;
end;

Hay que hacer esto porque por defecto cuando se crea una ventana hija y se cierra, realmente no se cierra si no que se minimiza. Por ello he creado el evento AlCerrar en la ventana padre para asignarlo a todas las ventanas hijas.

Si queremos hacer un formulario normal que no esté relacionado con el formulario padre MDI, entonces el procedimiento sería el siguiente:

procedure TFormulario.NormalClick( Sender: TObject );
var
Form: TForm;
begin
Form := TForm.Create( Self );
Form.Caption := 'Ventana normal';
Form.Show;
end;

Cuando se crea un formulario nuevo su propiedad FormStyle es por defecto fsNormal. El crear una ventana modal es prácticamente lo mismo:

procedure TFormulario.ModalClick( Sender: TObject );
var
Form: TForm;
begin
Form := TForm.Create( Self );
Form.Caption := 'Ventana modal';
Form.ShowModal;
end;

Cuando se crea una ventana hija MDI hay que tener presentes un par de cosas:

- Nunca pueden ser invisibles, con lo cual si utilizamos los métodos Show o Hide provocará un error. Igual para la propiedad Visible.

- Tampoco pueden ser modales, para ello utiliza una ventana modal como hemos visto anteriormente.

ORGANIZANDO LAS VENTANAS HIJAS

Una vez creadas las ventanas hijas, la ventana padre puede organizarlas en cascada, mostrarlas todas a la vez, colocarlas horizontalmente, verticalmente e incluso cerrarlas todas.

Por ejemplo, para poner todas las ventanas hijas en cascada hacemos lo siguiente:

procedure TFormulario.CascadaClick( Sender: TObject );
begin
VentanasNormales;
Cascade;
end;


El procedimiento VentanasNormales se encarga de dejar cada una de las ventanas hijas de manera normal por si acaso estaban minimizadas:

procedure TFormulario.VentanasNormales;
var i: Integer;
begin
for i := 0 to MDIChildCount - 1 do
MDIChildren[i].WindowState := wsNormal;
end;

La clase TForm dispone de las propiedades MDIChildCount y MDIChildren para controlar el número de ventanas hijas abiertas así como cada una de ellas.

Aparte de ponerlas en cascada podemos hacer que todas se repartan en pantalla horizontamente:

procedure TFormulario.HorizontalClick( Sender: TObject );
begin
VentanasNormales;
TileMode := tbHorizontal;
Tile;
end;



Y también verticalmente:

procedure TFormulario.VerticalClick( Sender: TObject );
begin
VentanasNormales;
TileMode := tbVertical;
Tile;
end;


Si queremos minimizarlas todas hay que decírselo a cada una de ellas:

procedure TFormulario.MinimizarClick( Sender: TObject );
var i: Integer;
begin
for i := MDIChildCount - 1 downto 0 do
MDIChildren[i].WindowState := wsMinimized;
end;


También ocurre lo mismo si queremos cerrarlas todas:

procedure TFormulario.CerrarClick( Sender: TObject );
var i: Integer;
begin
for i := 0 to MDIChildCount - 1 do
MDIChildren[i].Close;
end;

Las aplicaciones MDI son muy útiles para realizar programas de gestión, procesadores de texto, visualizadores de imágenes, etc.

Pruebas realizadas en Delphi 7.

4 comentarios:

Pcgames-raf dijo...

hola, tengo un problema, cuando yo creo formularios hijos estos se me abren automaticamente cuando inicio el sistema, como podría evitar eso?

Administrador dijo...

Tu mismo te has respondido a la pregunta.

Los formularios hijos MDI (MDI Child) aparecen en pantalla en el mismo momento que se crean. Siempre son visibles.

Son pequeñas chapuzas de la VCL y Windows. Lo que hay que hacer es no crearlo hasta que sea necesario.

Saludos.

Pcgames-raf dijo...

gracias por contestar :), por cierto muy bueno el blog me sirvieron muchas cosas asi que gracias.

eh logrado que no se creen al inicio, luego renegué para mostrarlos (porque no sabia que tenia que crearlos), utilize esta sentencia:
Form2:=TForm2.Create(Self);
Form2.Show;

ahora como hago para hacer un control que no permita abrir otro formulario igual mientras ese ya este abierto? porque queremos utilizar formularios realizados por nosotros.

si tenes gtalk agregame creo que te figura mi mail

Unknown dijo...

hola, como hicieron para que no se cree al inicio

Publicidad